RDLC报表LocalReport.Render 方法使用示例案例输出导出文件

LocalReport.Render
方法 (String, String, CreateStreamCallback, out Warning[])

Imports System.IO
Imports System.Data

Imports System.Text

Imports System.Drawing.Imaging

Imports System.Drawing.Printing

Imports System.Collections.Generic

Imports Microsoft.Reporting.WinForms
Public Class Demo

    Implements IDisposable
    private m_currentPageIndex As Integer

    private m_streams As IList(Of Stream)
    Private Function LoadSalesData() As DataTable

        Dim dataSet As New DataSet()

        dataSet.ReadXml("data.xml")

        Return dataSet.Tables(0)

    End Function
    Private Function CreateStream(name As String, _

         fileNameExtension As String, _

              encoding As Encoding, mimeType As String, _

                  willSeek As Boolean) As Stream

        Dim stream As Stream = New FileStream(name + "." +  fileNameExtension, FileMode.Create)

        m_streams.Add(stream)

        Return stream

    End Function
    Private Sub Export(report As LocalReport)

        Dim deviceInfo As string = _

          "<DeviceInfo>" + _

          "  <OutputFormat>EMF</OutputFormat>" + _

          "  <PageWidth>8.5in</PageWidth>" + _

          "  <PageHeight>11in</PageHeight>" + _

          "  <MarginTop>0.25in</MarginTop>" + _

          "  <MarginLeft>0.25in</MarginLeft>" + _

          "  <MarginRight>0.25in</MarginRight>" + _

          "  <MarginBottom>0.25in</MarginBottom>" + _

          "</DeviceInfo>"

        Dim warnings() As Warning = Nothing

        m_streams = New List(Of Stream)()

        report.Render("Image", deviceInfo, _

              AddressOf CreateStream, warnings)
        Dim stream As Stream

        For Each stream In m_streams

            stream.Position = 0

        Next

    End Sub
    Private Sub PrintPage(sender As Object, ev As PrintPageEventArgs)

        Dim pageImage As New Metafile(m_streams(m_currentPageIndex))

        ev.Graphics.DrawImage(pageImage, ev.PageBounds)
        m_currentPageIndex += 1

        ev.HasMorePages = (m_currentPageIndex < m_streams.Count)

    End Sub
    Private Sub Print()

        Const printerName As String = "Microsoft Office Document Image Writer"
        If m_streams Is Nothing Or m_streams.Count = 0 Then

            Return

        End If 
        Dim printDoc As New PrintDocument()

        printDoc.PrinterSettings.PrinterName = printerName

        If Not printDoc.PrinterSettings.IsValid Then

            Dim msg As String = String.Format(_

                 "Can't find printer ""{0}"".", printerName)

            Debug.WriteLine(msg)

            Return

        End If

        AddHandler printDoc.PrintPage, AddressOf PrintPage

        printDoc.Print()

    End Sub
    Private Sub Run()

        Dim report As LocalReport = new LocalReport()

        report.ReportPath = "Report.rdlc"

        report.DataSources.Add(new ReportDataSource("Sales", LoadSalesData()))
        Export(report)
        m_currentPageIndex = 0

        Print()

    End Sub
    Public Overloads Sub Dispose() Implements IDisposable.Dispose

        If Not (m_streams Is Nothing) Then

            Dim stream As Stream

            For Each stream In m_streams

               stream.Close()

            Next

            m_streams = Nothing

        End If

    End Sub
    Public Shared Sub Main(args as string())

        Using demo As Demo = new Demo()

            demo.Run()

        End Using

    End Sub

End Class

admin