使用反射访问特性VB.net

如果没有检索自定义特性的信息和对其进行操作的方法，则定义自定义特性并将其放置在源代码中就没有意义。 使用反射，可检索用自定义特性定义的信息。 主要方法是 GetCustomAttributes，它返回对象数组，这些对象在运行时等效于源代码特性。 此方法具有多个重载版本。 有关更多信息，请参见 Attribute。

<Author("P. Ackerman", Version:=1.1)> 
Class SampleClass
    ' P. Ackerman's code goes here...
End Class

在概念上等效于：
Dim anonymousAuthorObject As Author = New
Author(“P.
Ackerman”)
anonymousAuthorObject.version = 1.1

但是，直到查询 SampleClass 来获取特性后才会执行此代码。 对 SampleClass 调用 GetCustomAttributes 会导致按上述方式构造并初始化一个 Author对象。 如果该类具有其他特性，则按相似的方式构造其他特性对象。 然后 GetCustomAttributes 返回 Author 对象和数组中的任何其他特性对象。 之后就可以对此数组进行迭代，确定根据每个数组元素的类型所应用的特性，并从特性对象中提取信息。

示例

下面是一个完整的示例。 定义一个自定义特性，将其应用于若干实体并通过反射进行检索

' Multiuse attribute
<System.AttributeUsage(System.AttributeTargets.Class Or 
                       System.AttributeTargets.Struct, 
                       AllowMultiple:=True)> 
Public Class Author
    Inherits System.Attribute
    Private name As String
    Public version As Double
    Sub New(ByVal authorName As String)
        name = authorName

        ' Default value
        version = 1.0
    End Sub

    Function GetName() As String
        Return name
    End Function        
End Class

' Class with the Author attribute
<Author("P. Ackerman")> 
Public Class FirstClass
End Class

' Class without the Author attribute
Public Class SecondClass
End Class

' Class with multiple Author attributes.
<Author("P. Ackerman"), Author("R. Koch", Version:=2.0)> 
Public Class ThirdClass
End Class

Class TestAuthorAttribute
    Sub Main()
        PrintAuthorInfo(GetType(FirstClass))
        PrintAuthorInfo(GetType(SecondClass))
        PrintAuthorInfo(GetType(ThirdClass))
    End Sub

    Private Shared Sub PrintAuthorInfo(ByVal t As System.Type)
        System.Console.WriteLine("Author information for {0}", t)

        ' Using reflection
        Dim attrs() As System.Attribute = System.Attribute.GetCustomAttributes(t)

        ' Displaying output
        For Each attr In attrs
            Dim a As Author = CType(attr, Author)
            System.Console.WriteLine("   {0}, version {1:f}", a.GetName(), a.version)
        Next            
    End Sub

    ' Output:
    '   Author information for FirstClass
    '     P. Ackerman, version 1.00
    ' Author information for SecondClass
    ' Author information for ThirdClass
    '  R. Koch, version 2.00
    '  P. Ackerman, version 1.00

End Class